home *** CD-ROM | disk | FTP | other *** search
/ Cream of the Crop 11 / Cream of the Crop 11-1.iso / games / nerak2.zip / INITGAME.SCR < prev    next >
Text File  |  1995-10-02  |  5KB  |  150 lines
  1. !
  2. ! FILE : initgame.scr
  3. !
  4. ! DESCRIPTION
  5. !   Example introduction script.  This script is executed when the game
  6. !   is first started.  A party of a single player has been created with
  7. !   initial values set to those found in statistics record # 0, with
  8. !   the following additions:
  9. !
  10. !     group.gold        = 1000;   (1000 silver or 100 gold)
  11. !     group.food        =   25;
  12. !     player.name       = "John Doe";
  13. !     player.type       = 0; ! 'REGULAR' in the standard DCCTOKEN.DAT file
  14. !     player.class      = 0; ! 'HUMAN'   in the standard DCCTOKEN.DAT file
  15. !     player.level      = 1;
  16. !     player.experience = 1;
  17. !     player.energy     = 1000;
  18. !
  19. ! You may change any group and/or player attributes in this script, and
  20. ! may call the 'edit_player()' function to invoke the character creation
  21. ! screen.  This function accepts a the following parameters:
  22. !
  23. !   edit_player( which,                 (1 to 6, required)
  24. !                points to distribute   (0 to 40, default 25), 
  25. !                min attribute value    (0 to 255, default 9),
  26. !                max attribute value    (0 to 255, default 20),
  27. !                allow-name-edit        (1 = yes, 0 = no, default 1),
  28. !                allow-class-edit       (1 = yes, 0 = no, default 1),
  29. !                allow-block-edit       (1 = yes, 0 = no, default 1),
  30. !                allow-attribute-0-edit (1 = yes, 0 = no, default 1),
  31. !                allow-attribute-1-edit (1 = yes, 0 = no, default 1),
  32. !                ... );
  33. ! 
  34. ! Only the first parameter is required, all others may be omitted.
  35. !
  36. ! Note that the automatic adjustments for 'class' are now part of this
  37. ! script, instead of part of the 'edit_player' function.  They occur
  38. ! AFTER character creation.  A small price to pay for the flexibility
  39. ! provided by 'edit_player'.
  40. !
  41. ! If you don't wan't to use the character creation screen, you may set
  42. ! the attributes in many different ways, for example:
  43. !
  44. ! You might get the name this way:
  45. !   :XLOOP
  46. !     write( "What is your name: " );
  47. !     L0 = getstr( "Hey You" );
  48. !     if S0 = "" goto XLOOP;  ! You HAVE to enter a name
  49. !     player.name = S0;
  50. !
  51. ! You might set the class using a menu, as follows:
  52. !   L0 = select( "Wizard", "Elf", "Dwarf" );
  53. !   on L0 goto XWIZ, XELF, XDWARF;
  54. !   :XWIZ   player.class = WIZARD; goto XNEXT;
  55. !   :XELF   player.class = ELF;    goto XNEXT;
  56. !   :XDWARF player.class = DWARF;  goto XNEXT;
  57. !   :XNEXT
  58. !
  59. ! Or directly...
  60. !   player.class = ELF;
  61. !
  62. ! The standard attributes can be set directly in statistics record # 0
  63. ! (using the DCWORLD program) or in this script by direct assignment.
  64. !
  65. ! The usual values in the standard statistics record # 0 for the attribute
  66. ! fields is a 9.
  67. !
  68.  
  69. !------------------------------------------------------------------------!
  70.  
  71. ! Record how much memory is left after starting the game driver just
  72. ! in case I run into memory problems later and want to know this info.
  73.  
  74. system( "mem /C >freemem.xxx" );
  75. if failure then
  76.   writeln( "Couldn't run FREEMEM.XXX. Press <space>" );
  77.   pause;
  78. endif;
  79. ! Do the initial sequence of music, graphics, etc
  80. !
  81. music   ( "intro1.cmf" );  ! Play background music
  82. viewpcx ( "intro1.pcx" );  ! Show a nice picture
  83. wait    ( 120 );
  84. music   ( "intro2.cmf" );  ! Play background music
  85. readtext( "intro1.txt" );  ! Read some text.
  86.  
  87. !
  88. ! Now, create the player's character by using 'edit_player'
  89. !
  90.   edit_player( 1 );
  91.   on player.class goto XHUMAN,XELF,XDWARF,XWIZARD,XARCHER,XFIGHTER;
  92.  
  93.   ! any other, drop into 'XHUMAN'
  94.  
  95. :XHUMAN
  96.   goto DONE; ! No adjustments for 'Humans'
  97.  
  98. :XELF
  99.   inc( player.mspd );
  100.   dec( player.mstr );
  101.   inc( player.mpwr );
  102.   goto DONE;
  103.  
  104. :XDWARF
  105.   inc( player.mstr );
  106.   inc( player.mdex );
  107.   dec( player.mspd, 2 );
  108.   inc( player.mhp,  2 );
  109.   goto DONE;
  110.  
  111. :XWIZARD
  112.   inc( player.miq,  2 );
  113.   inc( player.mpwr, 3 );
  114.   dec( player.mstr, 3 );
  115.   dec( player.mhp,  2 );
  116.   goto DONE;
  117.  
  118. :XARCHER
  119.   inc( player.maim, 2 );
  120.   inc( player.mspd, 2 );
  121.   dec( player.mstr, 2 );
  122.   goto DONE;
  123.  
  124. :XFIGHTER
  125.   inc( player.mstr, 4 );
  126.   inc( player.mhp,  2 );
  127.   inc( player.miq,  4 );
  128.   goto DONE;
  129.  
  130. :DONE
  131.  
  132. ! Here, you may transfer the party to any location at which you wish
  133. ! the game to start. For example, to start in world 3, 2 squares 
  134. ! south (down) and 5 right from the location of door 7, use:
  135. !
  136. !   teleport( 3, world.doorx(7) + 5, world.doory(7) - 2 );
  137. !
  138. ! You may also set the group's X and Y location directly if you wish
  139. ! to alter the location within world zero.
  140. !
  141. ! The default start location is right over the location of door 0 in
  142. ! world 0.
  143. !
  144.  
  145.   dec( group.y ); ! Start example game 1 square above door 0 in world 0
  146.   music( stop );
  147.   STOP;  ! Use CONTINUE if you want the driver to invoke edit_player()
  148.  
  149.                                                                           
  150.